ModbusFB库中ModbusTCPMaster功能使用教程

yanxinyue

1、在库管理器中添加ModbusFB库

主要使用下面的FB功能块实现对各个数据区域的读写操作

2、下例为通过状态机循环轮询访问方式实现对保持寄存器的读写以及线圈的读写的操作

2.1FB功能块实例化以及相关变量定义

VAR

    // TCP 驱动

    fbTCP : ModbusFB.ClientTCP;

    aIPAddress : ARRAY[0..3] OF BYTE := [192, 168, 1, 7];

    xConnect: BOOL := TRUE;

    xConnected : BOOL;

    // ================== 读保持寄存器

    fbReadHolding : ModbusFB.ClientRequestReadHoldingRegisters;

    arReadData : ARRAY[0..9] OF WORD;

    // ================== 写保持寄存器

    fbWriteHolding : ModbusFB.ClientRequestWriteMultipleRegisters;

    uiWriteValue : ARRAY[0..9] OF WORD ; // 要写入的值

    // ================== 读线圈（0x）

    fbReadCoil : ModbusFB.ClientRequestReadCoils;

    bCoilValue : BOOL; // 读到的线圈状态

    // ================== 写线圈

    fbWriteCoil : ModbusFB.ClientRequestWriteSingleCoil;

    bSetCoil : BOOL := TRUE; // 要写的线圈状态

    // 状态机 + 定时

    tReadTimer : TON;

    eState : (IDLE, READ_HOLD, WRITE_HOLD, READ_COIL, WRITE_COIL) := IDLE;

    xExecute : BOOL;

END_VAR

2.2程序实现

// TCP 驱动配置

fbTCP.aIPAddr[0] := aIPAddress[0];

fbTCP.aIPAddr[1] := aIPAddress[1];

fbTCP.aIPAddr[2] := aIPAddress[2];

fbTCP.aIPAddr[3] := aIPAddress[3];

fbTCP.uiPort := 502;

fbTCP.xConnect := xConnect;

fbTCP();

// 1. 读保持寄存器 40001

fbReadHolding(

    rClient := fbTCP,

    xExecute := xExecute AND (eState = READ_HOLD),

    uiUnitId := 1,

    uiStartItem := 0,

    uiQuantity := 10,

    pData := ADR(arReadData)

);

// 2. 写保持寄存器 40001

fbWriteHolding(

    rClient := fbTCP,

    xExecute := xExecute AND (eState = WRITE_HOLD),

    uiUnitId := 1,

    uiStartItem:=10 ,

uiQuantity:= 10,

pData:=ADR(uiWriteValue));

// 3. 读线圈 00001

fbReadCoil(

    rClient := fbTCP,

    xExecute := xExecute AND (eState = READ_COIL),

    uiUnitId := 1,

    uiStartItem := 0,

    uiQuantity := 1,

    pData := ADR(bCoilValue)

);

// 4. 写线圈 00001

fbWriteCoil(

    rClient := fbTCP,

    xExecute := xExecute AND (eState = WRITE_COIL),

    uiUnitId := 1,

    uiItem := 0,

    xValue := bSetCoil

);

// 轮询状态机（自动轮流读写）

IF fbTCP.xConnected THEN

        CASE eState OF

            IDLE:

                eState := READ_HOLD;

            READ_HOLD:

     IF fbReadHolding.xDone OR fbReadHolding.xError  THEN

                    eState := WRITE_HOLD;

                END_IF;

            WRITE_HOLD:

             IF fbWriteHolding.xDone OR fbWriteHolding.xError THEN

                    eState := READ_COIL;

                END_IF;

            READ_COIL:

                IF fbReadCoil.xDone OR fbReadCoil.xError THEN

                    eState := WRITE_COIL;

                END_IF;

            WRITE_COIL:

                IF fbWriteCoil.xDone OR fbWriteCoil.xError THEN

                    eState := READ_HOLD;

                END_IF;

        END_CASE;

        xExecute := TRUE;

    ELSE

        xExecute := FALSE;

  eState := IDLE;

    END_IF;

来源: ModbusFB库中ModbusTCPMaster功能使用教程